Workplace Effectiveness: Dealing with Change/Workplace Effectiveness: Dealing with Change.iso/pc/Assess.Dxr/Internal_214_Change History code.ls

Text File | 1998-04-24 | 4.6 KB | 169 lines

global gMasterData, gHistoryList, gQuestionNum, checkMarks1

on startHistory
  go(label("History"))
  setUserArea(gMasterData, #history1)
end

on setUpHistory
  stopSound2()
  go("History1")
  set gQuestionNum to 1
  if voidp(gHistoryList) then
    set gHistoryList to [#empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty, #empty]
  end if
  showTheChoice()
  goNarrator(gMasterData, "13")
  setFingerCursor(#on, [5, 6, 7, 8])
  puppetSprite(3, 1)
end

on exitHistory1
  setPuppetState([3, 5, 6, 7, 8], #n, 0)
  setFingerCursor(#off, [5, 6, 7, 8])
end

on exitHistory2
  setPuppetState([5, 16], #c, 0)
  if getaProp(checkMarks1, #history) = 0 then
    setaProp(checkMarks1, #history, 1)
  end if
end

on goBackTo28
  stopSound2()
  go("History1")
  setUserArea(gMasterData, #history1)
  set gQuestionNum to 28
  setPuppetState([3, 8], #n, 1)
  set the member of sprite 3 to member ("question" && gQuestionNum)
  set the member of sprite 8 to member "CH done"
  showTheChoice()
  setFingerCursor(#on, [5, 6, 7, 8])
end

on historyChoice vTheseButtons, vThisChoice, vThisSprite
  repeat with X in vTheseButtons
    if X = vThisSprite then
      nothing()
      next repeat
    end if
    puppetSprite(X, 0)
  end repeat
  updateStage()
  setAt(gHistoryList, gQuestionNum, vThisChoice)
end

on nextQuestion
  if gQuestionNum < 28 then
    set gQuestionNum to gQuestionNum + 1
    set the member of sprite 3 to member ("question" && gQuestionNum)
    showTheChoice()
    if gQuestionNum = 28 then
      puppetSprite(8, 1)
      set the member of sprite 8 to member "CH done"
    end if
    updateStage()
  else
    historyResults()
  end if
end

on prevQuestion
  if gQuestionNum > 1 then
    if gQuestionNum = 28 then
      puppetSprite(8, 1)
      set the member of sprite 8 to member "CH next"
    end if
    updateStage()
    set gQuestionNum to gQuestionNum - 1
    set the member of sprite 3 to member ("question" && gQuestionNum)
    showTheChoice()
  end if
end

on showTheChoice
  set vAnswer to getAt(gHistoryList, gQuestionNum)
  setPuppetState([5, 7], #c, 0)
  case vAnswer of
    #Notwell:
      puppetSprite(5, 1)
      set the member of sprite 5 to member "notWell on"
    #JustOK:
      puppetSprite(6, 1)
      set the member of sprite 6 to member "justOK on"
    #Verywell:
      puppetSprite(7, 1)
      set the member of sprite 7 to member "veryWell on"
  end case
  updateStage()
end

on historyResults
  exitHistory1()
  go("wink")
end

on prepareGraph
  go(marker(1))
  setUserArea(gMasterData, #history2)
  stopSound2()
  DelaySome(30)
  set the editable of member "CH field" to 1
  updateStage()
  set vAnswerKey to [#home: [1, 6, 9, 10, 13, 14, 15, 17, 19, 21], #work: [2, 5, 7, 8, 11, 12, 13, 20, 21, 22], #relations: [1, 3, 4, 6, 9, 11, 15, 20, 25, 28], #self: [1, 8, 9, 16, 18, 23, 24, 26, 27, 28]]
  set vGraphResult to [#home: [0, 0, 0], #work: [0, 0, 0], #relations: [0, 0, 0], #self: [0, 0, 0]]
  repeat with X = 1 to count(gHistoryList)
    repeat with vProp in [#home, #work, #relations, #self]
      if getOne(getProp(vAnswerKey, vProp), X) <> 0 then
        case getAt(gHistoryList, X) of
          #empty:
            set vTester to 0
          #Notwell:
            set vTester to 1
          #JustOK:
            set vTester to 2
          #Verywell:
            set vTester to 3
        end case
        if vTester > 0 then
          set vThisNum to getAt(getProp(vGraphResult, vProp), vTester)
          set vThisNum to vThisNum + 1
          setAt(getProp(vGraphResult, vProp), vTester, vThisNum)
        end if
      end if
    end repeat
  end repeat
  showGraph(vGraphResult)
end

on showGraph vGraphResult
  global gMasterData
  set vThisSprite to 5
  set bottomV to 314
  set topV to 124
  set vNewNotch to (bottomV - topV) / 10
  repeat with vProp in [#home, #work, #relations, #self]
    repeat with vListPos = 1 to 3
      set vAnswer to getAt(getProp(vGraphResult, vProp), vListPos)
      if vAnswer > 0 then
        set vEndPositionV to bottomV - (vAnswer * vNewNotch)
        AnimateGraph(vThisSprite, vEndPositionV)
      end if
      set vThisSprite to vThisSprite + 1
    end repeat
  end repeat
  goNarrator(gMasterData, "14")
end

on AnimateGraph vThisSprite, vEndPositionV
  set vStartLocH to the locH of sprite vThisSprite
  set vNewLocV to the locV of sprite vThisSprite
  puppetSprite(vThisSprite, 1)
  repeat while vNewLocV >= vEndPositionV
    set vNewLocV to vNewLocV - 2
    set the loc of sprite vThisSprite to point(vStartLocH, vNewLocV)
    updateStage()
  end repeat
end